1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
AC_INIT([libplay], [1.0], [vcaputo@pengaru.com])
AM_INIT_AUTOMAKE([-Wall -Werror foreign])
AC_PROG_CC
AC_CONFIG_HEADERS([config.h])
AM_PROG_CC_C_O
AM_PROG_AR
AC_PROG_RANLIB
AM_SILENT_RULES([yes])
CFLAGS="$CFLAGS -Wall"
dnl Check for SDL2
PKG_CHECK_MODULES(SDL2, sdl2)
CFLAGS="$CFLAGS $SDL2_CFLAGS"
LIBS="$LIBS $SDL2_LIBS"
dnl Check for SDL2_mixer unless --with-audio=no, fails when missing and --with-audio=yes
AC_ARG_WITH(
[audio],
[AS_HELP_STRING([--with-audio], [Enable audio/music API via SDL2_mixer @<:@default=check@:>@])],
[],
[with_audio=check])
AS_CASE(
["$with_audio"],
[yes], [PKG_CHECK_MODULES(SDL2_MIXER, SDL2_mixer, [HAVE_MIXER=1])],
[no], [HAVE_MIXER=0],
[PKG_CHECK_MODULES(SDL2_MIXER, SDL2_mixer, [HAVE_MIXER=1], [HAVE_MIXER=0])])
dnl this gets the define for compilation
AS_IF([test "x$HAVE_MIXER" = x1], [AC_DEFINE([WITH_AUDIO],[],[Enable audio/music API])])
dnl this gets the define for Makefile.am
AM_CONDITIONAL([WITH_AUDIO], [test "x$HAVE_MIXER" = x1])
LIBS="$SDL2_MIXER_LIBS $LIBS"
CFLAGS="$SDL2_MIXER_CFLAGS $CFLAGS"
AC_CONFIG_FILES([
Makefile
src/Makefile
])
AC_OUTPUT
|
